/*
$Header: /repo/video.cvs/studio/inventory/image/stands.scad,v 1.1 2017/07/19 06:54:03 bruce Exp $

openscad stands.scad
*/

$fa = 5;
$fs = 2;
$fn = 50;

module fTube(pLen) {
    difference() {
        cylinder(h=pLen,d1=1.25,d2=1.25,center=true);
        cylinder(h=pLen+.1,d1=1,d2=1,center=true);
    }
} // fTube

module fCouple(pLen) {
    difference () {
        cylinder(h=pLen,d1=1.75,d2=1.75,center=true);
        cylinder(h=pLen+1,d1=1.25,d2=1.25,center=true);
    }
} //fCouple

module fTubeC(pLen) {
    fTube(pLen);
    translate([0,0,pLen/2]) {
        fCouple(2.5);
     }
} // fTubeC

module fTee() {
    rotate([0,90,0]) {
    difference() {
        translate([-1,0,0]) {
            rotate([0,90,0]) {
                difference(){
                    cylinder(h=2,d1=1.75,d2=1.75,center=true);
                    cylinder(h=2.1,d1=1.25,d2=1.25,center=true);
                }
            }
        }
        cylinder(h=3.76,d1=1.25,d2=1.25,center=true);
    }
    difference() {
        cylinder(h=3.75,d1=1.75,d2=1.75,center=true);
        cylinder(h=3.76,d1=1.25,d2=1.25,center=true);
        translate([-1,0,0]) {
            rotate([0,90,0]) {
                cylinder(h=1.1,d1=1.25,d2=1.25,center=true);
            }
        }
    }
    }
} // fTee

module fMidTee() {
    fTee();
    for (x = [3,-3]) {
        translate([x,0,0]) {
            rotate([0,90,0]) {
                fTube(6);
            }
        }
    }
} // fMidTee

module fFootTee() {
    fMidTee();
    for (x = [6,-6]) {
        translate([x,0,0]) {
            rotate([0,90,0]) {
                difference () {
                    fCouple(2.5);
                }
            }
        }
    }
} // fFootTee

module fFoot() {
    fMidTee();
    translate([9,0,0]) {
        rotate([-90,0,90]) {
            fFootTee();
        }
    }
    rotate([0,180,0]) {
        translate([9,0,0]) {
            rotate([-90,0,90]) {
                fFootTee();
            }
        }
    }
} // fFoot

module fElbow() {
    sphere(d=1.8);
    translate([0,0,1]) {
        fCouple(1.5);
    }
    rotate([0,-90,0]) {
        translate([0,0,1]) {
            fCouple(1.5);
        }
    }
} // fElbow

module fStand() {
    fFoot();
    translate([0,0,12+3]) {
        fTubeC(24);
    }
    translate([0,0,24+12+6]) {
        fTubeC(24);
    }
} // fStand

module fScreenFrame() {
    rotate([0,0,90]) {
        fFoot();
    }
    translate([0,0,6+3]) {
        fTubeC(12);
    }
    translate([0,0,12+6]) {
        fTube(2);
    }
    translate([0,0,12+7+3]) {
        rotate([0,-90,0]) {
            fTee();
        }
    }
    translate([0,0,24+10+3]) {
        fTubeC(24);
//        text("x2");
    }
    translate([-12-3,0,12+7+3]) {
        rotate([0,-90,0]) {
            fTubeC(24);
        }
//        text("x3");
    }
    translate([0,0,49+3]) {
        fTube(2);
    }
    translate([0,0,49+4+3]) {
        rotate([0,-90,0]) {
            fElbow();
        }
    }
    translate([-12-3,0,49+4+3]) {
        rotate([0,-90,0]) {
            fTubeC(24);
        }
        // text("x3");
    }
    translate([-24-6,0, 12+7+3]) {
         rotate([0,90,0]) {
            fTube(2);
        }
    }
    translate([-24-6,0, 49+4+3]) {
         rotate([0,90,0]) {
            fTube(2);
        }
    }
} // fScreenFrame

//------------------------------

/* Basic parts
translate([7,7,0]) {
fTubeC(24);
}
translate([-7,-7,0]) {
    fTube(2);
}
translate([0,7,-6]) {
    fTee();
}
translate([-10,-12,-6]) {
fElbow();
}
*/

translate([25,0,0]) {
fStand();
}

fScreenFrame();